it-swarm-fr.com

Actualisation de tous les tableaux croisés dynamiques de mon classeur Excel avec une macro

J'ai un classeur avec 20 tableaux croisés dynamiques différents. Existe-t-il un moyen simple de rechercher tous les tableaux croisés dynamiques et de les actualiser dans VBA?

78
Lipis

Oui.

ThisWorkbook.RefreshAll

Ou, si votre version Excel est assez vieille,

Dim Sheet as WorkSheet, Pivot as PivotTable
For Each Sheet in ThisWorkbook.WorkSheets
    For Each Pivot in Sheet.PivotTables
        Pivot.RefreshTable
        Pivot.Update
    Next
Next
161
GSerg

Ce code VBA actualisera tous les tableaux croisés dynamiques/graphiques du classeur.

Sub RefreshAllPivotTables()

Dim PT As PivotTable
Dim WS As Worksheet

    For Each WS In ThisWorkbook.Worksheets

        For Each PT In WS.PivotTables
          PT.RefreshTable
        Next PT

    Next WS

End Sub

Une autre option non programmatique est:

  • Clic droit sur chaque tableau croisé dynamique
  • Sélectionnez les options de la table
  • Cochez l'option 'Actualiser à l'ouverture'.
  • Cliquez sur le bouton OK

Cela actualisera le tableau croisé dynamique chaque fois que le classeur est ouvert.

26
Robert Mearns

ActiveWorkbook.RefreshAll rafraîchit tout, pas seulement les tableaux croisés dynamiques, mais également les requêtes ODBC. J'ai quelques requêtes VBA qui font référence à des connexions de données et l'utilisation de cette option se bloque lorsque la commande exécute les connexions de données sans les détails fournis par VBA.

Je recommande l'option si vous voulez seulement rafraîchir les pivots

Sub RefreshPivotTables()     
  Dim pivotTable As PivotTable     
  For Each pivotTable In ActiveSheet.PivotTables         
    pivotTable.RefreshTable     
  Next 
End Sub 
20
Kevin

Dans certaines circonstances, vous souhaiterez peut-être différencier un tableau croisé dynamique de son tableau croisé dynamique. Le cache a sa propre méthode d'actualisation et ses propres collections. Nous aurions donc pu actualiser tous les tableaux croisés dynamiques au lieu des tableaux croisés dynamiques.

La différence? Lorsque vous créez un nouveau tableau croisé dynamique, il vous est demandé si vous le souhaitez basé sur un tableau précédent. Si vous dites non, ce tableau croisé dynamique obtient son propre cache et double la taille des données source. Si vous dites oui, votre carnet de travail reste petit, mais vous ajoutez à une collection de tableaux croisés dynamiques partageant un seul cache. Toute la collection est actualisée lorsque vous actualisez l'un des tableaux croisés dynamiques de cette collection. Vous pouvez donc imaginer la différence entre l'actualisation de chaque cache du classeur et l'actualisation de chaque tableau croisé dynamique.

8
Steve WahWah Weeks

Il y a une option d'actualiser tout dans la barre d'outils du tableau croisé dynamique. C'est assez. Ne pas avoir à faire autre chose.

Appuyez sur ctrl + alt + F5

5
Prasenjit

Vous avez une collection PivotTables sur un VB Feuille de travail objet. Donc, une boucle rapide comme celle-ci fonctionnera:

Sub RefreshPivotTables()
    Dim pivotTable As PivotTable
    For Each pivotTable In ActiveSheet.PivotTables
        pivotTable.RefreshTable
    Next
End Sub

Notes des tranchées:

  1. N'oubliez pas de déprotéger les feuilles protégées avant de mettre à jour le tableau croisé dynamique.
  2. Sauvegarder souvent.
  3. Je penserai à plus et mettrai à jour en temps voulu ... :)

Bonne chance!

1
LohanJ

Même nous pouvons actualiser une connexion particulière et à son tour, il actualisera tous les pivots qui lui sont liés.

Pour ce code, j'ai créé un slicer à partir d'une table présente dans Excel:

Sub UpdateConnection()
        Dim ServerName As String
        Dim ServerNameRaw As String
        Dim CubeName As String
        Dim CubeNameRaw As String
        Dim ConnectionString As String

        ServerNameRaw = ActiveWorkbook.SlicerCaches("Slicer_ServerName").VisibleSlicerItemsList(1)
        ServerName = Replace(Split(ServerNameRaw, "[")(3), "]", "")

        CubeNameRaw = ActiveWorkbook.SlicerCaches("Slicer_CubeName").VisibleSlicerItemsList(1)
        CubeName = Replace(Split(CubeNameRaw, "[")(3), "]", "")

        If CubeName = "All" Or ServerName = "All" Then
            MsgBox "Please Select One Cube and Server Name", vbOKOnly, "Slicer Info"
        Else
            ConnectionString = GetConnectionString(ServerName, CubeName)
            UpdateAllQueryTableConnections ConnectionString, CubeName
        End If
    End Sub

    Function GetConnectionString(ServerName As String, CubeName As String)
        Dim result As String
        result = "OLEDB;Provider=MSOLAP.5;Integrated Security=SSPI;Persist Security Info=True;Initial Catalog=" & CubeName & ";Data Source=" & ServerName & ";MDX Compatibility=1;Safety Options=2;MDX Missing Member Mode=Error;Update Isolation Level=2"
        '"OLEDB;Provider=SQLOLEDB.1;Integrated Security=SSPI;Persist Security Info=True;Initial Catalog=" & CubeName & ";Data Source=" & ServerName & ";Use Procedure for Prepare=1;Auto Translate=True;Packet Size=4096;Use Encryption for Data=False;Tag with column collation when possible=False"
        GetConnectionString = result
    End Function

    Function GetConnectionString(ServerName As String, CubeName As String)
    Dim result As String
    result = "OLEDB;Provider=MSOLAP.5;Integrated Security=SSPI;Persist Security Info=True;Initial Catalog=" & CubeName & ";Data Source=" & ServerName & ";MDX Compatibility=1;Safety Options=2;MDX Missing Member Mode=Error;Update Isolation Level=2"
    GetConnectionString = result
End Function

Sub UpdateAllQueryTableConnections(ConnectionString As String, CubeName As String)
    Dim cn As WorkbookConnection
    Dim oledbCn As OLEDBConnection
    Dim Count As Integer, i As Integer
    Dim DBName As String
    DBName = "Initial Catalog=" + CubeName

    Count = 0
    For Each cn In ThisWorkbook.Connections
        If cn.Name = "ThisWorkbookDataModel" Then
            Exit For
        End If

        oTmp = Split(cn.OLEDBConnection.Connection, ";")
        For i = 0 To UBound(oTmp) - 1
            If InStr(1, oTmp(i), DBName, vbTextCompare) = 1 Then
                Set oledbCn = cn.OLEDBConnection
                oledbCn.SavePassword = True
                oledbCn.Connection = ConnectionString
                oledbCn.Refresh
                Count = Count + 1
            End If
        Next
    Next

    If Count = 0 Then
         MsgBox "Nothing to update", vbOKOnly, "Update Connection"
    ElseIf Count > 0 Then
        MsgBox "Update & Refresh Connection Successfully", vbOKOnly, "Update Connection"
    End If
End Sub
0
Rajiv Singh

Le code

Private Sub Worksheet_Activate()
    Dim PvtTbl As PivotTable
        Cells.EntireColumn.AutoFit
        For Each PvtTbl In Worksheets("Sales Details").PivotTables
        PvtTbl.RefreshTable
        Next
End Sub 

fonctionne bien.

Le code est utilisé dans le module d’activation de la feuille, ainsi il affiche un scintillement/problème lorsque la feuille est activée.

0
user3564681